Short logger example

All the existing SD card examples in the Philower arduino-pico works as long as you make sure to specify the correct SPI bus in the begin statement. Check out the code below and specifically the SD.begin statement, here we can use the core defined expressions for the pin and the SPI bus.

The example also shows how to use the on board RTC to generate a time stamp for each group of measured samples.

/*
SD card datalogger

This example shows how to log data from four analog sensors
to an SD card using the SD library and tag each sample group
with a time stamp.

The circuit:
analog sensors on analog ins 0, 1, 2 and 3
The SD card is attached to SPI1 and uses pin 9 for card select.
Pin 13 is used to detect if a card is inserted or not.

created 24 Nov 2010
modified 9 Apr 2012
by Tom Igoe
Modified 31 oct 2022 to work with Challenger RP2040 SD/RTC
by P Oldberg

This example code is in the public domain.

*/

#include <SPI.h>
#include <SD.h>
#include <Wire.h>
#include <MCP79412RTC.h>

int anPins[] = {A0, A1, A2, A3};
MCP79412RTC RTC;

void setup() {
  // Open serial communications and wait for port to open:
  while (!Serial)
  delay(10);
  Serial.begin(115200);

  Serial.println("Checking if there is an SD card inserted !");
  pinMode(SD_CARD_DETECT, INPUT_PULLUP);
  if (digitalRead(SD_CARD_DETECT)) {
    Serial.println("No card inserted, wait for reset !");
    while(1);
  }

  Serial.print("Initializing SD card...");
  // see if the card is present and can be initialized.
  // Notice the use of core defined pin and SPI channel
  if (!SD.begin(SDCARD_CS_PIN, SD_SPI)) {
    Serial.println("Card failed, or not present, waiting for a reset.");
    while(1);
  }
  Serial.println("card initialized.");

  Serial.println("Synchronizing time !");
  RTC.begin();
  setSyncProvider(RTC.get); // the function to get the time from the RTC
  if (timeStatus()!= timeSet)
    Serial.println("Unable to sync with the RTC");
  else
    Serial.println("RTC has set the system time");
}

void loop() {
  char tmbuf[64];
  snprintf(tmbuf, 64, "%04d-%02d-%02dT%02d:%02d:%02d|", year(), month(), day(), hour(), minute(), second());
  String dataString = String(tmbuf);

  // read three sensors and append to the string:
  for (int analogPin = 0; analogPin < 4; analogPin++) {
    int sensor = analogRead(anPins[analogPin]);
    dataString += String(sensor);
    if (analogPin < 3) {
      dataString += ",";
    }
  }

  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.txt", FILE_WRITE);

  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  }
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  }
  delay(2000);
}