Running your Challenger 840 BLE on a battery – Part 2

/*********************************************************************
 * This example sets the system up for low power operation and
 * creates an Eddystone beacon that chugs along forever.
 *********************************************************************/
#include <bluefruit.h>
#include <nrf_soc.h>

//#define DEBUG

#if defined(DEBUG)
  #define Debug(arg)     Serial.print(arg)
  #define Debugln(arg)   Serial.println(arg)
#else
  #define Debug(arg)
  #define Debugln(arg)
#endif  

#define URL   "https://www.ilabs.se"
// Create an EddyStone URL with rssi at 0m = -40 and URL as defined above
EddyStoneUrl eddyUrl(-40, URL);

void setup() 
{
  /*
   * First setup hardware
   */
  // Set all pins to a known low power safe state.
  for(int i=0;i<PINS_COUNT;i++) {
    pinMode(i, INPUT_PULLUP);
  }

  // Configure LED pins
  pinMode(LED_GREEN, OUTPUT);
  digitalWrite(LED_GREEN, LOW);
  pinMode(LED_BLUE, OUTPUT);
  digitalWrite(LED_BLUE, LOW);
  
  // Switch of RGB LED and Bi2C connector power.
  pinMode(PIN_LDO_CONTROL, OUTPUT);
  digitalWrite(PIN_LDO_CONTROL, LOW);

  // Since we have switched of power to the LED we need to
  // bring the clk/data pin low to avoid current leakage.
  pinMode(LED_NEOPIXEL, OUTPUT);
  digitalWrite(LED_NEOPIXEL, LOW);

  // Configure external FLASH SPI pins so that the flash memory
  // enters stand by mode. If lower FLASH current is needed a
  // power down command can be sent to the flash.
  pinMode(PIN_SPI1_CS, OUTPUT);
  digitalWrite(PIN_SPI1_CS, HIGH);
  pinMode(PIN_SPI1_SCK, OUTPUT);
  digitalWrite(PIN_SPI1_SCK, LOW);
  pinMode(PIN_SPI1_MOSI, OUTPUT);
  digitalWrite(PIN_SPI1_MOSI, LOW);
  pinMode(PIN_SPI1_MISO, INPUT_PULLDOWN);

  // Set internal analog reference to 3.0V
  analogReference(AR_INTERNAL_3_0);

#if defined(DEBUG)
  while(!Serial)
    delay(10);
  Serial.begin(115200);
#endif

  Debugln("Bluefruit52 EddyStone URL Example");
  Debugln("---------------------------------\n");

  Bluefruit.begin();
  Bluefruit.setTxPower(4);      // Check bluefruit.h for supported values
  Bluefruit.autoConnLed(0);   // Disable connection LED

  // Setup the advertising packet
  startAdv();

  Debug("Battery voltage: ");
  Debugln(analogRead(PIN_VBAT));
  Debug("Supply voltage: ");
  Debugln(analogReadVDD());  

  Debugln("Broadcasting EddyStone URL, can be found by most Android beacon scanners.");
}

void startAdv(void)
{  
  // Advertising packet
  // Set the beacon payload using the BLEBeacon class populated
  // earlier in this example
  Bluefruit.Advertising.setBeacon(eddyUrl);

  // Secondary Scan Response packet (optional)
  // Since there is no room for 'Name' in Advertising packet
  Bluefruit.ScanResponse.addName();
  
  /* Start Advertising
   * - Enable auto advertising if disconnected
   * - Timeout for fast mode is 10 seconds
   * - Start(timeout) with timeout = 0 will advertise forever (until connected)
   * 
   */
  Bluefruit.Advertising.restartOnDisconnect(true);
  Bluefruit.Advertising.addTxPower();
  Bluefruit.Advertising.setIntervalMS(500, 2000);    // in unit of 0.625 ms
  Bluefruit.Advertising.setFastTimeout(10);       // number of seconds in fast mode
  Bluefruit.Advertising.start(0);                // 0 = Don't stop advertising after n seconds
}

void loop() 
{
  delay(1000);
}

  // Set all pins to a known low power safe state.
  for(int i=0;i<PINS_COUNT;i++) {
    pinMode(i, INPUT_PULLUP);
  }

  // Configure LED pins
  pinMode(LED_GREEN, OUTPUT);
  digitalWrite(LED_GREEN, LOW);
  pinMode(LED_BLUE, OUTPUT);
  digitalWrite(LED_BLUE, LOW);

  // Switch of RGB LED and Bi2C connector power.
  pinMode(PIN_LDO_CONTROL, OUTPUT);
  digitalWrite(PIN_LDO_CONTROL, LOW);

  // Since we have switched of power to the LED we need to
  // bring the clk/data pin low to avoid current leakage.
  pinMode(LED_NEOPIXEL, OUTPUT);
  digitalWrite(LED_NEOPIXEL, LOW);

  // Configure external FLASH SPI pins so that the flash memory
  // enters stand by mode. If lower FLASH current is needed a
  // power down command can be sent to the flash.
  pinMode(PIN_SPI1_CS, OUTPUT);
  digitalWrite(PIN_SPI1_CS, HIGH);
  pinMode(PIN_SPI1_SCK, OUTPUT);
  digitalWrite(PIN_SPI1_SCK, LOW);
  pinMode(PIN_SPI1_MOSI, OUTPUT);
  digitalWrite(PIN_SPI1_MOSI, LOW);
  pinMode(PIN_SPI1_MISO, INPUT_PULLDOWN);